Test simple d’incrémentation d’une valeur à l’aide de l’encodeur rotatif

Présentation

Ce programme teste l’encodeur rotatif avec interruption timer 2 à intervalle régulier et réalise l’incrémentation/décrémentation d’une valeur numérique à l’aide l’encodeur.

Ce programme utilise les fonctionnalités suivantes :

• Utilise un afficheur TFT 65536 couleurs Graphique 132×176 type S65
• Utilise l’Encodeur Rotatif du module S65
• Utilise interruption du Timer 2 à intervalle régulier

Voir également :

• Module d’affichage à écran couleur Arduino S65 shield
• Librairie pour afficheur TFT couleur S65
• Librairie pour l’encodeur rotatif du module S65 Shield
• Ce programme utilise une interruption à intervalle régulier générée à partir de la librairie MsTimer2 : Librairie MsTimer2(en anglais)

Matériel Nécessaire

L’espace de développement Arduino

• … pour éditer, compiler le programme et programmer la carte Arduino.

Le matériel suivant pour réaliser le montage associé

• un module avec afficheur couleur TFT 176×132

Acheté ici ( 35 Euros TTC seulement !) : http://www.watterott.com/en/Arduino-S65-Shield
Documentation ici : Module d’affichage à écran couleur Arduino S65 shield
Librairie pour afficheur TFT couleur S65

Instructions de montage

Le module S65 Shield est à enficher directement broche à broche sur la carte Arduino réalisant ainsi les connexions suivantes :
Ecran graphique S65 TFT contrôlé par 5 broches :

• broche S65_DAT du module sur la broche 11 de la carte Arduino
• broche S65_CLK du module sur la broche 13 de la carte Arduino
• broche S65_RS du module sur la broche 4 de la carte Arduino
• broche S65_RST du module sur la broche 17 de la carte Arduino
• broche S65_CS du module sur la broche 16 de la carte Arduino

Encodeur rotatif contrôlé par 3 broches :

• broche RE_SW du module sur la broche 5 de la carte Arduino
• broche RE_PhA du module sur la broche 6 de la carte Arduino
• broche RE_PhB du module sur la broche 7 de la carte Arduino

Le schéma théorique du montage

Le circuit du montage

Explication du programme

Structure globale du programme

Ce programme simple comprend :

• une entête déclarative
• une partie « configuration » qui ne sera exécutée qu’une fois (fonction setup( ) )
• une partie constituée d’une boucle sans fin que le programme répètera à l’infini ( fonction loop( ) ) : c’est le coeur du programme.

Déroulement du programme

Le programme se déroule de la façon suivante :

• Après avoir pris en compte les instructions de la partie déclarative,
• puis après avoir exécuté la partie configuration ( fonction setup( ) ),
• le programme bouclera sans fin ( fonction loop ( ) ), exécutant de façon répétée le code compris dans la boucle sans fin.

Une interruption est par ailleurs générée toutes les millisecondes à l’aide du Timer 2 : toutes les millisecondes, l’état de l’encodeur rotatif est analysé et les fonctions de la librairie renvoient la valeur correspondant à l’état de l’encodeur rotatif.

Pour plus de détails, voir :

• Librairie pour l’encodeur rotatif du module S65 Shield
• Ce programme utilise une interruption à intervalle régulier générée à partir de la librairie MsTimer2 : Librairie MsTimer2(en anglais)

Au niveau de la partie déclarative :

Inclusion des librairies utilisées

• On inclut les librairies des fonctionnalités utilisées :
  • Inclusion de la librairie pour l’afficheur TFT couleur S65 :

#include <S65Display.h> // Inclusion de la librairie pour afficheur TFT couleur S65 

• Inclusion de la librairie pour encodeur rotatif du module S65 :

#include <RotaryEncoder.h> // Inclusion de la librairie pour encodeur rotatif du module S65 

• Inclusion de la librairie pour interruption à intervalle régulier avec le Timer 2 :

#include <MsTimer2.h> // inclusion de la librairie Timer2

Déclaration de constantes utiles

• On déclare les constantes utiles dans le programme :

Déclaration des constantes de broches

• Déclaration des constantes pour les broches utilisées dans le programme :

Déclaration des variables globales

• Déclaration des variables globales du programmes :

On déclare une variable de comptage de type int avec le qualificateur volatile afin que cette variable soit utilisable dans la routine d’interruption. On déclare également une variable de mémorisation de la dernière valeur du comptage :

volatile int compt=0;
int compt0=0;

Déclarations des objets utiles pour les fonctionnalités utilisées

• Déclaration des objets utiles pour les fonctionnalités utilisées :
  • Déclaration d’un objet afficheur TFT couleur S65 :

S65Display lcd; // Création d'un objet afficheur S65 appelé lcd 

• Déclaration d’un objet encodeur rotatif :

RotaryEncoder encodeur; // Création d'un objet RotaryEncoder appelé encodeur 

Au niveau de la fonction d’initialisation setup( ) :

Initialisation des fonctionnalités utilisées :

• On initialise les différentes fonctionnalités utilisées :
  • Initialisation de l’afficheur TFT couleur S65 : on initialise l’afficheur et on réalise un test de fonctionnement en affichant des couleurs d’écran différentes.

lcd.init(4); // initialise l'afficheur TFT couleur S65 avec communication SPI à Fosc/4 = 4 Mhz

// test de l'afficheur 
lcd.clear(RGB(255,0,0)); // efface ecran en rouge
delay (1000); // pause
lcd.clear(RGB(0,255,0)); // efface ecran en vert
delay (1000); // pause
lcd.clear(RGB(0,0,255)); // efface ecran en bleu
delay (1000); // pause
lcd.clear(RGB(255,255,255)); // efface ecran en blanc

• Initialisation de l’encodeur rotatif du module S65

encodeur.init(); // initialise l'encodeur rotatif du module S65 sur les broches 5,6,7.

• Initialisation de l’interruption à intervalle régulier avec le Timer 2 : on initialise pour une interruption toutes les millisecondes. On appelle InterruptTimer2 la fonction de gestion de l’interruption qui sera utilisée. On active le Timer 2.

// initialisation interruption Timer 2
MsTimer2::set(1, InterruptTimer2); // période 1ms 
MsTimer2::start(); // active Timer2 

• On réalise l’affichage initial sur l’écran :

// affichage de départ sur le LCD
  lcd.drawText(40,48,"    ",3,jaune,bleu); // affiche espace propreté
  lcd.drawInteger(40, 48, compt, DEC, 3, jaune, bleu); // afficheur valeur de comptage

Au niveau de la boucle principale, la fonction loop ( ) :

• Dans une première condition, on teste si la variable de comptage a été modifiée. Si c’est le cas, on réalise un nouvel affichage de la valeur :

if (compt!=compt0) 
{
  lcd.drawText(40,48,"    ",3,jaune,bleu); //Affiche espace propreté
  lcd.drawInteger(40, 48, compt, DEC, 3, jaune, bleu); // affiche valeur comptage
  compt0=compt;
}

• Dans une seconde condition, on teste à l’aide de la fonction sw (sw pour switch) si le bouton poussoir d’axe a été appuyé. Si c’est le cas, on remet à zéro la variable de comptage :

if (encodeur.sw()==SW_PRESSED) // si appui axe encodeur
{
  compt=0; // RAZ le compteur
  lcd.drawText(40,48,"    ",3,jaune,bleu); // affiche espace propreté
  lcd.drawInteger(40, 48, compt, DEC, 3, jaune, bleu); // afficheur valeur de comptage
}

• Le programme recommence en boucle les instructions de la fonction loop( ).

Se reporter aux commentaires présents dans le programme pour plus de détails.

Autres Fonctions du programme :

• Dans la fonction InterruptTimer2, on assure la gestion de l’encodeur à l’aide de la fonction service de la librairie RotaryEncoder. On incrémente le compteur en conséquence également à l’aide de la fonction step:

void InterruptTimer2() { // debut de la fonction d'interruption Timer2

encodeur.service(); // appel de la routine de gestion de l'encodeur 
compt=compt+encodeur.step();

}

Mise en oeuvre du programme

Préparation du montage et programmation de la carte Arduino :

• Commencer par réaliser le montage indiqué sur plaque d’expérimentation
• Ensuite, programmer la carte Arduino avec ce programme (en bas de page) selon la procédure habituelle

Fonctionnement

• La rotation de l’encodeur fait incrémenter/décrémenter la valeur affichée sur l’écran.

Le programme complet en langage Arduino :

A copier/coller directement dans l’éditeur Arduino

// --- Programme Arduino ---
// Copyright X. HINAULT - Créé le 03/04/2010
// www.mon-club-elec.fr 

//  Code sous licence GNU GPL : 
//  This program is free software: you can redistribute it and/or modify
//  it under the terms of the GNU General Public License as published by
//  the Free Software Foundation, either version 3 of the License,
//  or any later version.
//  This program is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//  GNU General Public License for more details.
//  You should have received a copy of the GNU General Public License
//  along with this program.  If not, see <http://www.gnu.org/licenses/>.
//  

// --- Que fait ce programme ? ---
/* test encodeur rotatif avec interruption timer 2 à intervalle régulier*/

// --- Fonctionnalités utilisées ---
// Utilise un afficheur TFT 65536 couleurs Graphique 132x176 type S65
// Utilise l'Encodeur Rotatif du module S65 
// Utilise interruption du Timer 2 à intervalle régulier

// --- Circuit à réaliser ---
// Le module S65 Shield est à enficher directement broche à broche  
// sur la carte Arduino réalisant ainsi les connexions suivantes : 
// Ecran graphique S65 TFT contrôlé par 5 broches : 
// 	> broche S65_DAT du module sur la broche 11 de la carte Arduino 
// 	> broche S65_CLK du module sur la broche 13 de la carte Arduino 
// 	> broche S65_RS du module sur la broche 4 de la carte Arduino 
// 	> broche S65_RST du module sur la broche 17 de la carte Arduino 
// 	> broche S65_CS du module sur la broche 16 de la carte Arduino 
//
// Encodeur rotatif contrôlé par 3 broches : 
// 	> broche RE_SW du module sur la broche 5 de la carte Arduino 
// 	> broche RE_PhA du module sur la broche 6 de la carte Arduino 
// 	> broche RE_PhB du module sur la broche 7 de la carte Arduino 

//**************** Entête déclarative *******
// A ce niveau sont déclarées les librairies, les constantes, les variables...

// --- Inclusion des librairies utilisées ---

#include <S65Display.h> // Inclusion de la librairie pour afficheur TFT couleur S65 

#include <RotaryEncoder.h> // Inclusion de la librairie pour encodeur rotatif du module S65 
#include <MsTimer2.h> // inclusion de la librairie Timer2

// --- Déclaration des constantes ---

// --- constantes des broches ---


// --- Déclaration des variables globales ---
volatile int compt=0;
int compt0=0;

// --- Déclaration des objets utiles pour les fonctionnalités utilisées ---

S65Display lcd; // Création d'un objet afficheur S65 appelé lcd 


RotaryEncoder encodeur; // Création d'un objet RotaryEncoder appelé encodeur 


//**************** FONCTION SETUP = Code d'initialisation *****
// La fonction setup() est exécutée en premier et 1 seule fois, au démarrage du programme

void setup()   { // debut de la fonction setup()

// --- ici instructions à exécuter au démarrage --- 

lcd.init(4); // initialise l'afficheur TFT couleur S65 avec communication SPI à Fosc/4 = 4 Mhz

// test de l'afficheur 
lcd.clear(RGB(255,0,0)); // efface ecran en rouge
delay (1000); // pause 
lcd.clear(RGB(0,255,0)); // efface ecran en vert
delay (1000); // pause 
lcd.clear(RGB(0,0,255)); // efface ecran en bleu
delay (1000); // pause 
lcd.clear(RGB(255,255,255)); // efface ecran en blanc

encodeur.init(); // initialise l'encodeur rotatif du module S65 sur les broches 5,6,7.


// ------- Broches en sortie -------  


// ------- Broches en entrée -------  


// ------- Activation du rappel au + interne des broches en entrée si nécessaire -------  

// initialisation interruption Timer 2
  MsTimer2::set(1, InterruptTimer2); // période 1ms 
  MsTimer2::start(); // active Timer 2 

// affichage de départ sur le LCD
  lcd.drawText(40,48,"    ",3,jaune,bleu); // affiche espace propreté
  lcd.drawInteger(40, 48, compt, DEC, 3, jaune, bleu); // afficheur valeur de comptage

} // fin de la fonction setup()
// ********************************************************************************

//*************** FONCTION LOOP = Boucle sans fin = coeur du programme *************
// la fonction loop() s'exécute sans fin en boucle aussi longtemps que l'Arduino est sous tension

void loop(){ // debut de la fonction loop()

// --- ici instructions à exécuter par le programme principal --- 

//variable = encodeur.step(); // renvoie état courant de l'encodeur = valeur 0,1 ou -1
//variable = encodeur.sw(); // renvoie état courant du BP de l'axe de l'encodeur = valeur 0, SW_PRESSED, SW_PRESSEDLONG

if (compt!=compt0) 
{
  lcd.drawText(40,48,"    ",3,jaune,bleu); //Affiche espace propreté
  lcd.drawInteger(40, 48, compt, DEC, 3, jaune, bleu); // affiche valeur comptage
  compt0=compt;
}

if (encodeur.sw()==SW_PRESSED) // si appui axe encodeur
{
  compt=0; // RAZ le compteur
  lcd.drawText(40,48,"    ",3,jaune,bleu); // affiche espace propreté
  lcd.drawInteger(40, 48, compt, DEC, 3, jaune, bleu); // afficheur valeur de comptage
}

} // fin de la fonction loop() - le programme recommence au début de la fonction loop sans fin
// ********************************************************************************

//*************** Autres Fonctions du programme *************

void InterruptTimer2() { // debut de la fonction d'interruption Timer2

encodeur.service(); // appel de la routine de gestion de l'encodeur 
compt=compt+encodeur.step();

}
// --- Fin programme ---