1. Présentation
Ce programme réalise l’affichage en continu d’une mesure analogique sous forme de courbe sur un afficheur couleur TFT 176×132 pixel, type S65 réalisant un oscilloscope numérique simple.
Ce programme utilise les fonctionnalités suivantes :
- Utilise un afficheur TFT 65536 couleurs Graphique 132×176 type S65
- la conversion analogique numérique 10bits sur les voies analogiques analog 0,
Voir également :
2. Matériel Nécessaire
2.1 L’espace de développement Arduino
- … pour éditer, compiler le programme et programmer la carte Arduino.
2.2 Le matériel suivant pour réaliser le montage associé
- une plaque d’essai pour montage sans soudures,
- des straps,
- une résistance variable linéaire de 10 KOhms,
- un module avec afficheur couleur TFT 176×132
Acheté ici ( 35 Euros TTC seulement !) : http://www.watterott.com/en/Arduino-S65-Shield
Documentation ici : Module d’affichage à écran couleur Arduino S65 shield
Librairie pour afficheur TFT couleur S65
3. Instructions de montage
Le module S65 Shield est à enficher directement broche à broche sur la carte Arduino réalisant ainsi les connexions suivantes :
- broche S65_DAT du module sur la broche 11 de la carte Arduino
- broche S65_CLK du module sur la broche 13 de la carte Arduino
- broche S65_RS du module sur la broche 4 de la carte Arduino
- broche S65_RST du module sur la broche 17 de la carte Arduino
- broche S65_CS du module sur la broche 16 de la carte Arduino
La résistance analogique est connectée sur la broche analogique 0
- Broche Analog 0 (=broche 14) en entrée Analogique
4. Le schéma théorique du montage
Le schéma théorique du montage
5. Le circuit du montage
Le schéma du montage à réaliser
6. Explication du programme
6.1 Structure globale du programme
Ce programme simple comprend :
- une entête déclarative
- une partie « configuration » qui ne sera exécutée qu’une fois (fonction setup( ) )
- une partie constituée d’une boucle sans fin que le programme répètera à l’infini ( fonction loop( ) ) : c’est le coeur du programme.
6.2 Déroulement du programme
Le programme se déroule de la façon suivante :
- Après avoir pris en compte les instructions de la partie déclarative,
- puis après avoir exécuté la partie configuration ( fonction setup( ) ),
- le programme bouclera sans fin ( fonction loop ( ) ), exécutant de façon répétée le code compris dans la boucle sans fin.
Le déroulement du programme
7. Au niveau de la partie déclarative :
Inclusion des librairies utilisées
- On inclut les librairies des fonctionnalités utilisées :
- Inclusion de la librairie pour l’afficheur TFT couleur S65 :
#include <S65Display.h> // Inclusion de la librairie pour afficheur TFT couleur S65
Déclaration de constantes utiles
- On déclare les constantes utiles dans le programme :
Déclaration des constantes de broches
- Déclaration des constantes pour les broches utilisées dans le programme :
const int Voie_0=0; //declaration constante de broche analogique
Déclaration des variables globales
- Déclaration des variables globales du programmes :
- Déclaration des variables globales utilisées pour la conversion analogique-numérique
int mesure_brute=0;// Variable pour acquisition résultat brut de conversion analogique numérique float mesuref=0.0;// Variable pour calcul résultat décimal de conversion analogique numérique
-
- Déclaration des variables globales utilisées pour le tracé de la courbe :
int x_graph=0, y_graph=0; int x0_graph=0, y0_graph=0;
Déclarations des objets utiles pour les fonctionnalités utilisées
- Déclaration des objets utiles pour les fonctionnalités utilisées :
- Déclaration d’un objet afficheur TFT couleur S65 :
S65Display lcd; // Création d'un objet afficheur S65 appelé lcd
8. Au niveau de la fonction d’initialisation setup( ) :
Initialisation des fonctionnalités utilisées :
- On initialise les différentes fonctionnalités utilisées :
- Initialisation de l’afficheur TFT couleur S65
lcd.init(4); // initialise l'afficheur TFT couleur S65 avec communication SPI à Fosc/4 = 4 Mhz lcd.clear(RGB(255,0,0)); // efface ecran en rouge delay (1000); // pause lcd.clear(RGB(0,255,0)); // efface ecran en vert delay (1000); // pause lcd.clear(RGB(0,0,255)); // efface ecran en bleu delay (1000); // pause
9. Au niveau de la boucle principale, la fonction loop ( ) :
- On crée une boucle qui parcourt l’axe des abscisses à l’aide de la variable S65_WIDTH qui correspond à la largeur de l’écran en pixels (176 en l’occurence.
- A chaque fois :
- On efface le tracé précédent à l’aide d’une ligne de la même couleur que le fonc de l’écran
- on réalise une mesure analogique et on la réétalonne sur la hauteur de l’écran
- on affiche une ligne entre le point précédent et le nouveau point correspondant.
- on mémorise les coordonnées courantes pour le tracé suivant.
- on utilise une pause pour ne pas avoir un tracé trop rapide.
- En sortie de boucle, on réinitialise la variable xo pour éviter un tracé de retour.
for (int i=0; i<S65_WIDTH-1; i++) {
// O,0 est le coin sup gauche de l'écran - La 1ère ligne est 0
x_graph=i; // largeur = 176 x hauteur = 132
//---- ligne d'effacement du point précédent - même couleur que fond ---
lcd.drawLine(i, 0, i, 131, RGB( 0,0,255)); //attention - max x = 131
mesure_brute = analogRead (Voie_0); // mesure 0 - 1023
y_graph=map(mesure_brute,0,1023,1,132);
//lcd.drawPixel(x_graph, S65_HEIGHT-y_graph,RGB(255,255,0));
// --- affichage sous forme de courbe continue ---
lcd.drawLine(x0_graph, S65_HEIGHT-y0_graph, x_graph, S65_HEIGHT-y_graph, RGB(255,255,0));
x0_graph=x_graph; // mémorise n-1
y0_graph=y_graph; // mémorise y-1
delay(50);
}
x0_graph=0; // réinitialise xo_graph à la sortie de boucle
- Le programme recommence en boucle les instructions de la fonction loop( ).
Se reporter aux commentaires présents dans le programme pour plus de détails.
10. Mise en oeuvre du programme
10.1 Préparation du montage et programmation de la carte Arduino :
- Commencer par réaliser le montage indiqué sur plaque d’expérimentation
- Ensuite, programmer la carte Arduino avec ce programme (en bas de page) selon la procédure habituelle
10.2 Fonctionnement
- L’écran affiche la courbe correspondant à la mesure en cours. En faisant varier la valeur de l’entrée analogique, on fait varier la courbe.
11. Le programme complet en langage Arduino :
A copier/coller directement dans l’éditeur Arduino
// --- Programme Arduino ---
// Copyright X. HINAULT - Créé le 20/03/2010
// www.mon-club-elec.fr
// Code sous licence GNU GPL :
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License,
// or any later version.
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <http://www.gnu.org/licenses/>.
//
// --- Que fait ce programme ? ---
/* réalise un petit oscilloscope à écran couleur
en affichant en continu le résultat de la mesure
de la tension en sortie d'une résistance variable. */
// --- Fonctionnalités utilisées ---
// Utilise un afficheur TFT 65536 couleurs Graphique 132x176 type S65
// Utilise la conversion analogique numérique 10bits sur les voies analogiques analog 0,
// --- Circuit à réaliser ---
// Le module S65 Shield est à enficher directement broche à broche
// sur la carte Arduino réalisant ainsi les connexions suivantes :
// > broche S65_DAT du module sur la broche 11 de la carte Arduino
// > broche S65_CLK du module sur la broche 13 de la carte Arduino
// > broche S65_RS du module sur la broche 4 de la carte Arduino
// > broche S65_RST du module sur la broche 17 de la carte Arduino
// > broche S65_CS du module sur la broche 16 de la carte Arduino
// Broche Analog 0 (=broche 14) en entrée Analogique
//**************** Entête déclarative *******
// A ce niveau sont déclarées les librairies, les constantes, les variables...
// --- Inclusion des librairies utilisées ---
#include <S65Display.h> // Inclusion de la librairie pour afficheur TFT couleur S65
// --- Déclaration des constantes ---
// --- constantes des broches ---
const int Voie_0=0; //declaration constante de broche analogique
// --- Déclaration des variables globales ---
int mesure_brute=0;// Variable pour acquisition résultat brut de conversion analogique numérique
float mesuref=0.0;// Variable pour calcul résultat décimal de conversion analogique numérique
int x_graph=0, y_graph=0;
int x0_graph=0, y0_graph=0;
// --- Déclaration des objets utiles pour les fonctionnalités utilisées ---
S65Display lcd; // Création d'un objet afficheur S65 appelé lcd
//**************** FONCTION SETUP = Code d'initialisation *****
// La fonction setup() est exécutée en premier et 1 seule fois, au démarrage du programme
void setup() { // debut de la fonction setup()
// --- ici instructions à exécuter au démarrage ---
lcd.init(4); // initialise l'afficheur TFT couleur S65 avec communication SPI à Fosc/4 = 4 Mhz
lcd.clear(RGB(255,0,0)); // efface ecran en rouge
delay (1000); // pause
lcd.clear(RGB(0,255,0)); // efface ecran en vert
delay (1000); // pause
lcd.clear(RGB(0,0,255)); // efface ecran en bleu
delay (1000); // pause
// ------- Broches en sortie -------
// ------- Broches en entrée -------
// ------- Activation du rappel au + interne des broches en entrée si nécessaire -------
} // fin de la fonction setup()
// ********************************************************************************
//*************** FONCTION LOOP = Boucle sans fin = coeur du programme *************
// la fonction loop() s'exécute sans fin en boucle aussi longtemps que l'Arduino est sous tension
void loop(){ // debut de la fonction loop()
// --- ici instructions à exécuter par le programme principal ---
for (int i=0; i<S65_WIDTH-1; i++) {
// O,0 est le coin sup gauche de l'écran - La 1ère ligne est 0
x_graph=i; // largeur = 176 x hauteur = 132
//---- ligne d'effacement du point précédent - même couleur que fond ---
lcd.drawLine(i, 0, i, 131, RGB( 0,0,255)); //attention - max x = 131
mesure_brute = analogRead (Voie_0); // mesure 0 - 1023
y_graph=map(mesure_brute,0,1023,1,132);
//lcd.drawPixel(x_graph, S65_HEIGHT-y_graph,RGB(255,255,0));
// --- affichage sous forme de courbe continue ---
lcd.drawLine(x0_graph, S65_HEIGHT-y0_graph, x_graph, S65_HEIGHT-y_graph, RGB(255,255,0));
x0_graph=x_graph; // mémorise n-1
y0_graph=y_graph; // mémorise y-1
delay(50);
}
x0_graph=0; // réinitialise xo_graph à la sortie de boucle
} // fin de la fonction loop() - le programme recommence au début de la fonction loop sans fin
// ********************************************************************************
//*************** Autres Fonctions du programme *************
// --- Fin programme ---
