View  Edit  Attributes  History  Attach  Print  Search


ACCUEIL | DOCUMENTATION | STRATEGIES | TESTS


Librairie JavacvPro

Classe OpenCV : sobel2()


Exemple comparatif fonction sobel() et sobel2') avec noyau 3x3, coeff normalisation=4 et coeff=1

Description

  • Cette fonction ré-implémente le filtre de Sobel qui est un algorithme de détection de contour par noyau de convolution à l'aide de la fonction OpenCV native cvFilter2D. L'intérêt ici par rapport à la fonction sobel() est de pouvoir utiliser un noyau "non-normalisé" ou partiellement normalisé (càd dire que la division des coefficients du noyau par la taille du noyau est affectée d'un coefficient atténuateur). Il en résulte la possibilité d'accentuer à volonté l'intensité du contour.
  • Pour la petite histoire, l'écriture de cette fonction m'a été inspirée par le bon résultat que j'obtenais avec un filtre de Sobel que j'avais écrit dans Processing et qui utilisait un noyau non-normalisé. Voir ici : Processing – Traitement d'image : Filtre Sobel 2D (détection de contours)
  • A noter que l'utilisation des fonctions natives OpenCV (cvFilter2D) pour réaliser ce filtre abouti à une vitesse d'exécution rapide. Voir : http://opencv.itseez.com/modules/imgproc/doc/filtering.html#filter2d
  • Cet algorithme est paramétré essentiellement par la taille du noyau, mais également donc par un coefficient de normalisation. Un coefficient multiplicateur peut également être appliqué pour accentuer le contour.
  • A noter que cet algorithme s'applique sur une image RGB et renvoie un résultat RGB.
  • A noter que la fonction native OpenCV est unidirectionnelle. La présente fonction implémente le filtre Sobel de façon bi-directionnelle : le filtre Sobel est appliqué en vertical puis le filtre Sobel est appliqué en horizontal. Les 2 sont ensuite combinés pour obtenir le contour complet.
  • Enfin, l'application du filtre de Sobel nécessite l'utilisation d'une image supportant les valeurs signées négatives. La présente fonction gère automatiquement le basculement vers une image intermédiaire en nombre signé puis rebascule le résultat en mode RGB 8 bits non signés classique.
  • Au total, l'utilisation de cette implémentation du filtre de Sobel est grandement simplifiée et puissante avec cette fonction comparativement à la fonction OpenCV native. De plus, là encore, le délai d'exécution de la fonction est court ( 3 ou 4 millisecondes) ce qui permet de l'utiliser en direct sur un flux vidéo issu d'une webcam !
  • Voir également : canny(), sobel()
  • Pour plus d'informations, voir :

Déclaration source java

public void sobel2()
public void sobel2(float coeffNormIn)
public void sobel2 (int ksizeIn, float scaleIn, float coeffNormIn)
public opencv_core.IplImage sobel2 (opencv_core.IplImage iplImgIn, int ksizeIn, float scaleIn, float coeffNormIn)

Syntaxe

opencv.sobel2(); // applique le filtre sur le buffer principal - noyau = 3 - coeff = 1
opencv.sobel(coeffNorm); // applique le filtre sur le buffer principal avec coeff de normalisation. Noyau=3 et coeff=1
opencv.sobel(ksize, scale, coeffNorm); // applique le filtre sur le buffer principal avec taille noyau, coeff normalisation et coefficient
opencv.sobel(iplImg, ksize, scale, coeffNorm); // applique le filtre sur l'objet IplImage avec taille noyau et coefficient

Paramètres

  • opencv : un objet OpenCV déclaré avec le constructeur OpenCV.
  • ksize : taille du noyau de convolution à utiliser. =3 par défaut pour noyau de 3x3 pixels.
  • scale : coefficient multiplicateur. =1 par défaut.
  • coeffNorm : coefficient de normalisation. Ce coefficient vient multiplier le coefficient normalisé. Le coefficient normalisé est le coefficient du noyau divisé par la taille du noyau au carré. Ainsi, pour un noyau 3x3, avec un coefficient de normalisation de , les coefficient du noyau sont appliqués avec un facteur 4/3x3.
  • iplImg : objet IplImage.

Valeur renvoyée

Aucune. L'image source est modifiée.

Utilisation type

  • Le filtre de sobel est typiquement utilisé pour extraire les contours avant l'application d'une détection de formes. On applique classiquement un seuillage après pour éliminer les éléments non désirés.
  • Ce filtre est également assez sympa pour convertir une photo en "dessin au fusain" : il suffit pour cela, une fois le filtre appliqué de basculer en niveau de gris puis d'inverser l'image. C'est magique ! Et dire que ce n'est que des maths...

Exemple


opencv.sobel2(); // applique le filtre de sobel2 sur le buffer principal OpenCV avec paramètres par défaut noyau = 3 et coeff=1)
opencv.sobel2(9); //applique le filtre de sobel2 sur le buffer principal OpenCV avec coeff normalisation - noyau 3x3 et coeff=1 par défaut
opencv.sobel2(3,4,1); //applique le filtre de sobel2 sur le buffer OpenCV désigné avec paramètres
opencv.sobel2(opencv.Buffer,3,9,1); //applique le filtre de sobel2 sur le buffer OpenCV désigné avec paramètres
 

L'exemple complet suivant est à copier dans Processing et est exécutable immédiatement si vous êtes connectés à internet :



// Programme d'exemple de la librairie javacvPro
// par X. HINAULT - octobre 2011
// Tous droits réservés - Licence GPLv3

// Exemple fonction sobel2()

import monclubelec.javacvPro.*; // importe la librairie javacvPro

PImage img;

String url="http://www.mon-club-elec.fr/mes_images/online/lena.jpg"; // String contenant l'adresse internet de l'image à utiliser

OpenCV opencv; // déclare un objet OpenCV principal

void setup(){ // fonction d'initialisation exécutée 1 fois au démarrage

        //-- charge image utilisée ---
        img=loadImage(url,"jpg"); // crée un PImage contenant le fichier à partir adresse web

        //--- initialise OpenCV ---
        opencv = new OpenCV(this); // initialise objet OpenCV à partir du parent This
        opencv.allocate(img.width, img.height); // initialise les buffers OpenCv à la taille de l'image

        opencv.copy(img); // charge le PImage dans le buffer OpenCV

        //--- initialise fenêtre Processing
        size (opencv.width()*3, opencv.height()); // crée une fenêtre Processing de la 2xtaille du buffer principal OpenCV
        //size (img.width, img.height); // aalternative en se basant sur l'image d'origine

        //--- affiche image de départ ---        
        image(opencv.getBuffer(),0,0); // affiche le buffer principal OpenCV dans la fenêtre Processing

        //--- opérations sur image ---

        //--- sobel() ---
        opencv.sobel(); //applique le filtre de sobel sur le buffer OpenCV désigné avec paramètres
        image(opencv.getBuffer(),opencv.width(),0); // affiche le buffer principal OpenCV dans la fenêtre Processing


        //--- sobel2() ---
        opencv.copy(img); // recharge le PImage dans le buffer OpenCV

        //-- toutes ces formes sont possibles :
        //opencv.sobel2(); // applique le filtre de sobel2 sur le buffer principal OpenCV avec paramètres par défaut noyau = 3 et coeff=1)
        //opencv.sobel2(9); //applique le filtre de sobel2 sur le buffer principal OpenCV avec coeff normalisation - noyau 3x3 et coeff=1 par défaut
        opencv.sobel2(3,4,1); //applique le filtre de sobel2 sur le buffer OpenCV désigné avec paramètres

        //opencv.sobel2(opencv.Buffer,3,9,1); //applique le filtre de sobel2 sur le buffer OpenCV désigné avec paramètres

        //--- pour effet "dessin au fusain"
        //opencv.gray(); // passage en niveau de gris
        //opencv.invert(); // pour dessin au trait noir sur blanc

        //--- affiche image finale ---
        image(opencv.getBuffer(),opencv.width()*2,0); // affiche le buffer principal OpenCV dans la fenêtre Processing

       noLoop(); // stop programme        
}


void  draw() { // fonction exécutée en boucle

}


 

Exemple webcam


// Programme d'exemple de la librairie javacvPro
// par X. HINAULT - Mars 2012
// Tous droits réservés - Licence GPLv3

// Exemple fonction Sobel2 - détection de contour par noyau de circonvolution

import codeanticode.gsvideo.*; // importe la librairie vidéo GSVideo qui implémente GStreamer pour Processing (compatible Linux)
// librairie comparable à la librairie native vidéo de Processing (qui implémente QuickTime..)- Voir Reference librairie Video Processing
// cette librairie doit être présente dans le répertoire modes/java/libraries du répertoire Processing (1-5)
// voir ici : http://gsvideo.sourceforge.net/

import monclubelec.javacvPro.*; // importe la librairie javacvPro

PImage img;

GSCapture cam; // déclare un objet GSCapture représentant une webcam
// L'objet GSCapture étend PImage - se comporte comme un conteneur des frames issues de la webcam

OpenCV opencv; // déclare un objet OpenCV principal

int widthCapture=320; // largeur image capture
int heightCapture=240; // hauteur image capture
int fpsCapture=30; // framerate de Capture

int millis0=0; // variable mémorisation millis()

void setup(){ // fonction d'initialisation exécutée 1 fois au démarrage

        //--- initialise fenêtre Processing
        size (widthCapture*2, heightCapture); // crée une fenêtre Processing de la 2xtaille du buffer principal OpenCV
        //size (img.width, img.height); // aalternative en se basant sur l'image d'origine
        frameRate(fpsCapture); // taux de rafraichissement de l'image

       //---- initialise la webcam ---
       //cam = new GSCapture(this, widthCapture, heightCapture); // forme simplifiée
       cam = new GSCapture(this, widthCapture, heightCapture,"v4l2src","/dev/video0", fpsCapture); // Initialise objet GSCapture désignant webcam - forme complète

        //--- initialise OpenCV ---
        opencv = new OpenCV(this); // initialise objet OpenCV à partir du parent This
        opencv.allocate(widthCapture, heightCapture); // initialise les buffers OpenCv à la taille de l'image

        cam.start();  // démarre objet GSCapture = la webcam

}


void  draw() { // fonction exécutée en boucle

// Code capture GSVideo

  if (cam.available() == true) { // si une nouvelle frame est disponible sur la webcam

        background(0);  // fond noir entre 2 images

        //------ gestion image webcam par GSCapture ------
        cam.read(); // acquisition d'un frame
        //image(cam1, 0, 0); // affiche image
        //set(0, 0, cam); // affiche image - plus rapide

        //------- gestion image par Opencv ----------

        //imgSrc=cam1.get(); // récupère l'image GS video dans Pimage
        //opencv.copy(imgSrc); // charge l'image dans le buffer openCV

        millis0=millis(); // mémorise millis()  
        opencv.copy(cam.get()); // autre possibilité - charge directement l'image GSVideo dans le buffer openCV
        println("Durée chargement buffer OpenCV=" + (millis()-millis0)+"ms.");

        //--- affiche image de départ avant opération sur image ---        
        image(opencv.getBuffer(),0,0); // affiche le buffer principal OpenCV dans la fenêtre Processing

        //--- opérations sur image ---

        millis0=millis(); // mémorise millis()  

        //-- toutes ces formes sont possibles :
        //opencv.sobel2(); // applique le filtre de sobel2 sur le buffer principal OpenCV avec paramètres par défaut noyau = 3 et coeff=1)
        //opencv.sobel2(9); //applique le filtre de sobel2 sur le buffer principal OpenCV avec coeff normalisation - noyau 3x3 et coeff=1 par défaut
        opencv.sobel2(3,4,1); //applique le filtre de sobel2 sur le buffer OpenCV désigné avec paramètres

        //opencv.sobel2(opencv.Buffer,3,9,1); //applique le filtre de sobel2 sur le buffer OpenCV désigné avec paramètres


        println("Durée traitement image par OpenCV=" + (millis()-millis0)+" ms.");

        //--- affiche image finale ---

        image(opencv.getBuffer(),widthCapture,0); // affiche le buffer principal OpenCV dans la fenêtre Processing        

  } // fin if available

} // fin draw
 

Durée d'exécution de la fonction

  • La réalisation de 100 exécutions successives de la fonction dans Processing (sur un Intel Dual Core à 2.33Gz sous Ubuntu 10.04 LTS avec la version OpenCV 2.3.1) pour une image de 320x240 donne une durée moyenne pour chaque exécution de :
    • de 10.16 ms en mode "interprété" soit une fréquence maximale potentielle de 10 fps.
    • de 10.16 ms en mode "compilé" soit une fréquence maximale potentielle de 10 fps.

Commentaires utilisateurs

Aucun

Cette page est une création originale de Xavier HINAULT - Tous droits réservés - 2011