View  Edit  Attributes  History  Attach  Print  Search


ACCUEIL | DOCUMENTATION | STRATEGIES | TESTS


Librairie JavacvPro

Classe OpenCV : mixerRGB()


Description

  • Cette fonction permet de combiner les canaux RGB entre eux en affectant chaque canal RGB d'un coefficient et additionnant la résultante dans un canal de sortie (canal rouge). Les 2 autres canaux restent inchangés.
  • Le calcul réalisé pixel par pixel est le suivant : R = (coefR x R) + (coefG x G) + (coefB x B). Il s'agit ici d'une implémentation à l'aide des fonctions natives OpenCV d'un outil disponible dans le logiciel Gimp.
  • Cette fonction donne de bons résultats pour discriminer efficacement des objets colorés. L'intérêt est beaucoup plus évident avec le canal de sortie en niveau de gris (voir mixerRGBGray()).
  • Cette fonction n'est pas une fonction native OpenCV. Mais le fait de l'implémenter à l'aide de fonctions natives OpenCV permet d'obtenir un temps d'exécution très court ( de l'ordre que quelques millisecondes) qui permet un usage en temps réel pour le traitement d'un flux vidéo issu d'un webcam. Une application type est le suivi d'objet coloré.
  • Voir également : multiply(), mixerRGBGray()

Déclaration source java

public void mixerRGB()
public void mixerRGB(float coeffRIn, float coeffGIn, float coeffBIn)
public void mixerRGB(opencv_core.IplImage iplImgIn, float coeffRIn, float coeffGIn, float coeffBIn)
public opencv_core.IplImage mixerRGB (opencv_core.IplImage iplImgIn, float coeffRIn, float coeffGIn, float coeffBIn, int canalOut, boolean grayOut, boolean debug)

Syntaxe

opencv.mixerRGB(); // mixerRGB appliqué par buffer principal avec détection couleur orangée
opencv.mixerRGB( coeffR, coeffG, coeffB); // mixerRGB appliqué sur objet IplImage avec paramètres
opencv.mixerRGB(iplImg, coeffR, coeffG, coeffB ); // mixerRGB appliqué sur objet IplImage avec paramètres
opencv.mixerRGB(iplImg, coeffR, coeffG, coeffB, canal, gray, debugIn); // mixerRGB appliqué sur objet IplImage avec paramètres

Paramètres

  • opencv : un objet OpenCV déclaré avec le constructeur OpenCV.
  • iplImg : objet IplImage
  • coeffR, coeffG, coeffB : coefficient à appliquer aux canaux respectifs - valeur négatives possibles. Si les valeurs finales sont inférieures ou supérieures aux limites maximales de l'image, elles prennent les valeurs 0 ou 255.
  • canal (int) : fixe le canal de sortie - pas implémenté - canal sortie rouge par défaut
  • gray (boolean) : drapeau d'activation de la sortie en niveaux de gris
  • debug (boolean) : drapeau d'activation des messages de debug

Valeur renvoyée

Aucune

Utilisation type

  • Cette fonction donne de bons résultats pour discriminer efficacement des objets colorés.

Exemple

opencv.mixerRGB(); // applique mixeur RGB sur le buffer principal OpenCV avec paramètres par défaut (1.0, 1.5,-2.0
opencv.mixerRGB(1.0,1.5, -2.0); // mixerRGB appliqué sur objet IplImage avec paramètres - ici détection couleur orangée

L'exemple complet suivant est à copier dans Processing et est exécutable immédiatement si vous êtes connectés à internet :


// Programme d'exemple de la librairie javacvPro
// par X. HINAULT - octobre 2011
// Tous droits réservés - Licence GPLv3

// Exemple fonction mixerRGB()

import monclubelec.javacvPro.*; // importe la librairie javacvPro

PImage img;

String url="http://www.mon-club-elec.fr/mes_images/online/ball.jpg"; // String contenant l'adresse internet de l'image à utiliser

OpenCV opencv; // déclare un objet OpenCV principal

void setup(){ // fonction d'initialisation exécutée 1 fois au démarrage

        //-- charge image utilisée ---
        img=loadImage(url,"jpg"); // crée un PImage contenant le fichier à partir adresse web

        //--- initialise OpenCV ---
        opencv = new OpenCV(this); // initialise objet OpenCV à partir du parent This
        opencv.allocate(img.width, img.height); // initialise les buffers OpenCv à la taille de l'image

        opencv.copy(img); // charge le PImage dans le buffer OpenCV

        //--- initialise fenêtre Processing
        size (opencv.width()*2, opencv.height()); // crée une fenêtre Processing de la 2xtaille du buffer principal OpenCV
        //size (img.width, img.height); // aalternative en se basant sur l'image d'origine

        //--- affiche image de départ ---        
        image(opencv.getBuffer(),0,0); // affiche le buffer principal OpenCV dans la fenêtre Processing

        //--- opérations sur image ---

        //-- toutes ces formes sont possibles :
        opencv.mixerRGB(); // applique mixeur RGB sur le buffer principal OpenCV avec paramètres par défaut

        //--- affiche image finale ---
        image(opencv.getBuffer(),opencv.width(),0); // affiche le buffer principal OpenCV dans la fenêtre Processing

       noLoop(); // stop programme        
}


void  draw() { // fonction exécutée en boucle

}

 

Exemple webcam



// Programme d'exemple de la librairie javacvPro
// par X. HINAULT - Mars 2012
// Tous droits réservés - Licence GPLv3

// Exemple fonction mixerRGB()

import codeanticode.gsvideo.*; // importe la librairie vidéo GSVideo qui implémente GStreamer pour Processing (compatible Linux)
// librairie comparable à la librairie native vidéo de Processing (qui implémente QuickTime..)- Voir Reference librairie Video Processing
// cette librairie doit être présente dans le répertoire modes/java/libraries du répertoire Processing (1-5)
// voir ici : http://gsvideo.sourceforge.net/

import monclubelec.javacvPro.*; // importe la librairie javacvPro

PImage img;

GSCapture cam; // déclare un objet GSCapture représentant une webcam
// L'objet GSCapture étend PImage - se comporte comme un conteneur des frames issues de la webcam

OpenCV opencv; // déclare un objet OpenCV principal

int widthCapture=320; // largeur image capture
int heightCapture=240; // hauteur image capture
int fpsCapture=30; // framerate de Capture

int millis0=0; // variable mémorisation millis()

void setup(){ // fonction d'initialisation exécutée 1 fois au démarrage

        //--- initialise fenêtre Processing
        size (widthCapture*2, heightCapture); // crée une fenêtre Processing de la 2xtaille du buffer principal OpenCV
        //size (img.width, img.height); // aalternative en se basant sur l'image d'origine
        frameRate(fpsCapture); // taux de rafraichissement de l'image

       //---- initialise la webcam ---
       cam = new GSCapture(this, widthCapture, heightCapture); // forme simplifiée
       //cam = new GSCapture(this, widthCapture, heightCapture,"v4l2src","/dev/video1", fpsCapture); // Initialise objet GSCapture désignant webcam - forme complète

        //--- initialise OpenCV ---
        opencv = new OpenCV(this); // initialise objet OpenCV à partir du parent This
        opencv.allocate(widthCapture, heightCapture); // initialise les buffers OpenCv à la taille de l'image

        cam.start();  // démarre objet GSCapture = la webcam

}


void  draw() { // fonction exécutée en boucle

// Code capture GSVideo

  if (cam.available() == true) { // si une nouvelle frame est disponible sur la webcam

        background(0);  // fond noir entre 2 images

        //------ gestion image webcam par GSCapture ------
        cam.read(); // acquisition d'un frame
        //image(cam1, 0, 0); // affiche image
        //set(0, 0, cam); // affiche image - plus rapide

        //------- gestion image par Opencv ----------

        //imgSrc=cam1.get(); // récupère l'image GS video dans Pimage
        //opencv.copy(imgSrc); // charge l'image dans le buffer openCV

        millis0=millis(); // mémorise millis()  
        opencv.copy(cam.get()); // autre possibilité - charge directement l'image GSVideo dans le buffer openCV
        println("Durée chargement buffer OpenCV=" + (millis()-millis0)+"ms.");

        //--- affiche image de départ avant opération sur image ---        
        image(opencv.getBuffer(),0,0); // affiche le buffer principal OpenCV dans la fenêtre Processing

        //--- opérations sur image ---

        millis0=millis(); // mémorise millis()  

        //-- toutes ces formes sont possibles :
        //opencv.mixerRGB(); // applique mixeur RGB sur le buffer principal OpenCV avec paramètres par défaut
        opencv.mixerRGBGray(1.0,1.5, -2.0); // mixerRGB appliqué sur objet IplImage avec paramètres - ici détection couleur orangée

        println("Durée traitement image par OpenCV=" + (millis()-millis0)+" ms.");

        //--- affiche image finale ---

        image(opencv.getBuffer(),widthCapture,0); // affiche le buffer principal OpenCV dans la fenêtre Processing        

  } // fin if available

} // fin draw
 

Durée d'exécution de la fonction

  • La réalisation de 100 exécutions successives de la fonction dans Processing (sur un Intel Dual Core à 2.33Gz sous Ubuntu 10.04 LTS avec la version OpenCV 2.3.1) pour une image de 320x240 donne une durée moyenne pour chaque exécution de :
    • de 3.51 ms en mode "interprété" soit une fréquence maximale potentielle de 280 fps.
    • de 3.33 ms en mode "compilé" soit une fréquence maximale potentielle de 300 fps.

Commentaires utilisateurs

Aucun

Cette page est une création originale de Xavier HINAULT - Tous droits réservés - 2011