View  Edit  Attributes  History  Attach  Print  Search


ACCUEIL | DOCUMENTATION | STRATEGIES | TESTS


Librairie JavacvPro

Classe OpenCV : bgsMOGInit(), bgsMOGApply()

Description

  • Ces fonctions implémentent un objet natif avancé de la librairie OpenCV qui permet de réaliser la soustraction du fond au sein d'une image issue d'un flux vidéo en se basant sur les "Mixture Of Gaussian" (MOG). Le sigle bgs signifie "BackGround Subtractor" (soustracteur d'arrière-plan).
  • Ces fonctions implémentent un objet qui va mémoriser n frames afin de réaliser un modèle statistique de l'évolution des pixels au fil du temps. Ce modèle va être analysé afin d'en extraire les populations de pixels cohérentes entre-elles ce qui va permettre de dégager le fond (background) de l'avant-plan (foreground).
  • Cet algorithme sera surtout efficace pour un avant plan mobile par rapport au fond.
  • Toute la puissance de cette fonction réside dans le fait de n'utiliser que une ou 2 lignes dans un programme Processing pour implémenter un algorithme complexe.
  • La documentation de le librairie native OpenCV :http://opencv.itseez.com/modules/video/doc/motion_analysis_and_object_tracking.html#backgroundsubtractormog
  • Voir également : absDiff(), accumulate(), bgsMOG2Init(), bgsMOG2Apply(), sum()
  • Pour plus d'informations théoriques :

Remarques techniques

  • Les objets de l'avant-plan qui restent immobiles vont peu à peu être inclus dans le fond et laisseront une "empreinte" que l'on retrouvera lorsque l'objet passera à nouveau dans la zone d'immobilisation.
  • En couplant des fonctions à la fonction sum(), on pourra déclencher des algorithmes de traitement uniquement lorsque un avant plan significatif sera détecté : par exemple une capture vidéo ou une analyse de forme.

Déclaration source java

public void bgsMOGInit()
public void bgsMOGInit(int history, int nmixtures, double backgroundRatio, double noiseSigma)

public void bgsMOGApply()
public void bgsMOGApply(opencv_core.IplImage iplImgSrcIn, opencv_core.IplImage iplImgDestIn, int modeIn)
 
[Obtenir le Code]

Syntaxe

Initialisation

opencv.bgsMOGInit(history, nmixtures, backgroundRatio, noiseSigma); // initialise l'objet MOG avec paramètres
opencv.bsgMOGInit(); // initialise l'objet MOG avec : history = 200; nmixture=5; backgroundRatio (threshold) = 0.7; noiseSigma=15;
[Obtenir le Code]

Utilisation

opencv.bgsMOGApply(iplImgSrc, iplImgDest, mode); // ajoute une image au modèle statistique du MOG
opencv.bgsMOGApply(); // ajoute une image au modèle statistique du MOG - source = Buffer principal et destination = Buffer Gray
[Obtenir le Code]

Paramètres

Fonction bsgMOGInit()

  • opencv : un objet OpenCV déclaré avec le constructeur OpenCV
  • history : nombre de frame à utiliser pour le modèle statistique. 200 par défaut. Plus on utilise d'image, et plus l'atténuation sera lente.
  • nmixture : nombre de "Mixture Of Gaussian" à utiliser, c'est à dire le nombre population de pixels à utiliser. 5 par défaut
  • backgroundRatio : seuil à utiliser - 0.7 par défaut
  • noiseSigma : paramètre fixant la gestion du bruit. 15 par défaut

Fonction bsgMOGApply()

  • opencv : un objet OpenCV déclaré avec le constructeur OpenCV.
  • iplImgSrc : image OpenCV source
  • iplImgDest : image OpenCV destination monocanal. La fonction renvoie le masque de l'avant plan c'est à dire une image binarisée où les pixels considérés comme l'avant plan sont en blanc.
  • mode : fixe le mode de fonctionnement de l'algorithme. Utiliser 0 en mode statique ou - 1 pour une actualisation automatique du modèle statistique (le mieux).

Fonctions de l'objet bsgMOG

Valeur renvoyée

Aucune. L'image résultante du traitement est dans l'image destination.

Utilisation type

  • Soustraction du fond et détection d'objet en mouvement.

Exemple

L'exemple complet suivant est à copier dans Processing et est exécutable immédiatement si vous disposez d'une webcam :


// Programme d'exemple de la librairie javacvPro
// par X. HINAULT - novembre 2011
// Tous droits réservés - Licence GPLv3

// Montre exemple utilisation de la fonction bgsMOGInit() et bgsMOGApply()


import codeanticode.gsvideo.*; // importe la librairie vidéo GSVideo qui implémente GStreamer pour Processing (compatible Linux)
// librairie comparable à la librairie native vidéo de Processing (qui implémente QuickTime..)- Voir Reference librairie Video Processing
// cette librairie doit être présente dans le répertoire modes/java/libraries du répertoire Processing (1-5)
// voir ici : http://gsvideo.sourceforge.net/
// et ici : http://codeanticode.wordpress.com/2011/05/16/gsvideo-09-release

import monclubelec.javacvPro.*; // importe la librairie javacvPro

GSCapture cam1; // déclare un objet GSCapture représentant une webcam
// L'objet GSCapture étend PImage - se comporte comme un conteneur des frames issues de la webcam

OpenCV opencv; // déclare un objet OpenCV principal

PImage imgSrc;

int widthCapture=320;
int heightCapture=240;
int fpsCapture=20;

void setup(){ // fonction d'initialisation exécutée 1 fois au démarrage

        size(widthCapture*2,heightCapture);

        //======== Initialisation Objets GSVideo (capture et/ou lecture video =========

        // GSCapture(this, int requestWidth, int requestHeight, [int frameRate], [String sourceName], [String cameraName])
         cam1 = new GSCapture(this, widthCapture, heightCapture); // forme simplifiée
        //cam1 = new GSCapture(this, widthCapture, heightCapture,fpsCapture,"v4l2src","/dev/video0"); // Initialise objet GSCapture désignant webcam
        // largeur et hauteur doivent être compatible avec la webcam - typiquement 160x120 ou 320x240 ou 640x480...
        // Meilleurs résultats avec framerate webcam entre 20 et 30 et frameRate programme idem ou multiple plus grand (40 pour 20 par ex)
        // la liste des webcam installées sous Ubuntu (Gnu/Linux) est donnée par la commande : ls /dev/video*

        // cam1.play();  // démarre objet GSCapture = la webcam - version GSVideo avant 0.9
        cam1.start();  // démarre objet GSCapture = la webcam - version GSVideo après 0.9

        //======== Initialisation Objets OpenCV (librairie javacvPro : traitement d'image et reconnaissance visuelle) =========

        opencv = new OpenCV(this); // initialise objet OpenCV à partir du parent This
        opencv.allocate(widthCapture,heightCapture); // crée le buffer image de la taille voulue


        //--- Initialisation objet MOG --- Un objet bsgMOG est déclaré en interne
        //opencv.bgsMOGInit(); // initialise bgsMOG avec paramètres par défaut
        // default : history = 200; nmixture=5; backgroundRatio (threshold) = 0.7; noiseSigma=15;        

        opencv.bgsMOGInit(20, 5, 0.5, 10); // initialise bgsMOG avec paramètres voulus

}


void  draw() { // fonction exécutée en boucle

  if (cam1.available() == true) { // si une nouvelle frame est disponible sur la webcam
    cam1.read(); // acquisition d'un frame

    imgSrc=cam1.get(); // récupère l'image GS video dans Pimage
    opencv.copy(imgSrc); // charge l'image dans le buffer openCV

    //opencv.copy(cam1.get()); // autre possibilité - charge directement l'image GSVideo dans le buffer openCV

    image(opencv.getBuffer(), 0, 0); // affiche image

    opencv.bgsMOGApply(opencv.Buffer, opencv.BufferGray, 0); // ajoute un frame à l'objet BackGround Subtractor MOG
    // la fonction initialise est appelée en interne au premier passage si besoin

    image(opencv.getBufferGray(), widthCapture, 0); // affiche image



  } // fin if available

} // fin draw
 
[Obtenir le Code]

Commentaires utilisateurs

Aucun

Cette page est une création originale de Xavier HINAULT - Tous droits réservés - 2011